;Coder, Turk, mırc kodları, TurkCoder.ORG
;CTRL+A tusuna basarak kodun hepsini kopyalayınız.

alias netstat {
  if ($dialog(netstat)) dialog -x netstat
  dialog -m netstat netstat
}
dialog netstat {
  title "Netstat"
  size -1 -1 448 308
  option dbu
  list 1, 11 12 424 283, size
}
on *:dialog:netstat:init:0:{
  var %com $+(cmd,$ticks) | .comopen %com wscript.shell
  if (!$comerr) .comclose %com $com(%com,run,1,bstr,cmd.exe /c pushd $mircdir && netstat -fo > $qt($mircdirshellout) 2>&1,uint,7,bool,true)
  var %x 1
  while (%x <= $lines(shellout)) {
    var %line = $read(shellout,n,%x)
    if ($regex(%line,(.+) (.+):(\d+) (.+):(\S+) (.+) (\d+))) {
      var %prot = $regml(1), %localip = $regml(2), %localport = $regml(3)
      var %remoteaddr = $regml(4), %remoteport = $regml(5), %state = $regml(6), %pid = $regml(7)
      ;echo -a %prot - %localip $+ : $+ %localport - %remoteaddr $+ : $+ %remoteport - %state - %pid
      hadd -m netstat_ $+ %localip $+ : $+ %localport prot %prot
      hadd -m netstat_ $+ %localip $+ : $+ %localport localip %localip
      hadd -m netstat_ $+ %localip $+ : $+ %localport localport %localport
      hadd -m netstat_ $+ %localip $+ : $+ %localport remoteaddr %remoteaddr
      hadd -m netstat_ $+ %localip $+ : $+ %localport remoteport %remoteport
      hadd -m netstat_ $+ %localip $+ : $+ %localport state %state
      hadd -m netstat_ $+ %localip $+ : $+ %localport pid %pid
    }
    inc %x
  }
  .remove shellout
  var %com $+(cmd,$ticks)
  .comopen %com wscript.shell
  if (!$comerr) .comclose %com $com(%com,run,1,bstr,cmd.exe /c pushd $mircdir && tasklist > $qt($mircdirshellout) 2>&1,uint,7,bool,true)
  var %x = 1
  while (%x <= $lines(shellout)) {
    var %line = $read(shellout,n,%x)
    tokenize 32 %line
    if (%x > 4) {
      var %proc = $1, %process_id = $2
      var %y = 1
      while ($hget(%y)) {
        var %table = $v1
        if (netstat_* iswm %table) {
          var %prot = $hget(%table,prot), %localip = $hget(%table,localip), %localport = $hget(%table,localport)
          var %remoteaddr = $hget(%table,remoteaddr), %remoteport = $hget(%table,remoteport), %state = $hget(%table,state), %pid = $hget(%table,pid)
          if (%pid == %process_id) {
            if (!$hget(%table,got)) {
              hadd -m %table got 1
              if ($dialog(netstat)) did -a netstat 1 %prot - %localip $+ : $+ %localport - %remoteaddr $+ : $+ %remoteport - %state - %proc
            }
          }
        }
        inc %y
      }
    }
    inc %x
  }
  .remove shellout
  .hfree -sw netstat_*
}